OpenWindow()

Syntaxe

Resultat = OpenWindow(#Fenetre, x, y, LargeurInterne, HauteurInterne, Titre$ [, Options [, FenetreMereID]])
Description
Ouvre une nouvelle fenêtre avec les paramètres spécifiés.

Arguments

#Fenetre Le numéro identifiant la nouvelle fenêtre.

Si #PB_Any est utilisé pour le paramètre '#Fenetre', le numéro de la fenêtre sera renvoyé dans 'Resultat'.
x, y Les coordonnées en pixels, de la position de la fenêtre (sauf si l'une des options de centrage est utilisée).

Si l'une d'elle est définie avec #PB_Ignore alors le système choisira une position pour la fenêtre.
LargeurInterne, HauteurInterne Les dimensions de la zone interne de la fenêtre ( dite zone cliente), sans les bordures, la barre de titre et autres décorations.
Titre$ Le titre de la nouvelle fenêtre.
Options (optionnel) Peut être une combinaison de :
  #PB_Window_SystemMenu     : Autorise le menu système sur la barre de titre.
  #PB_Window_MinimizeGadget : Ajoute l'icône 'Réduire' sur la barre de titre. #PB_Window_SystemMenu est ajouté automatiquement.
  #PB_Window_MaximizeGadget : Ajoute l'icône 'Agrandir' sur la barre de titre. #PB_Window_SystemMenu est ajouté automatiquement.
                              (MacOS : #PB_Window_SizeGadget sera également ajouté automatiquement).
  #PB_Window_SizeGadget     : Ajoute les possibilités de redimensionnement à la fenêtre.
  #PB_Window_Invisible      : Crée la fenêtre mais ne l'affiche pas.
  #PB_Window_TitleBar       : Crée la fenêtre avec une barre de titre.
  #PB_Window_BorderLess     : Crée une fenêtre sans bordure.
  #PB_Window_Tool           : Crée une fenêtre avec une barre de titre plus fine, et non visible dans la barre des tâches.
  #PB_Window_ScreenCentered : Centre la fenêtre au milieu de l'écran. Les paramètres x,y sont ignorés.
  #PB_Window_WindowCentered : Centre la fenêtre au milieu de la fenêtre mère ('FenetreMereID' doit être spécifié). Les paramètres x,y sont ignorés.
  #PB_Window_Maximize       : Ouvre la fenêtre en mode maximisé. (Note: sous Linux, certains gestionnaires de fenêtres ne supportent pas cela)
  #PB_Window_Minimize       : Ouvre la fenêtre en mode minimisé.
  #PB_Window_NoGadgets      : Empêche la création d'une GadgetList. UseGadgetList() peut être utilisé pour le faire plus tard.
  #PB_Window_NoActivate     : Ne pas activer la fenêtre après son ouverture.
FenetreMereID' (optionnel) Le numéro de la fenêtre mère.
'FenetreMereID' peut être obtenu facilement par la commande WindowID().

Valeur de retour

Renvoie une valeur non nulle si la création de la nouvelle fenêtre s'est bien déroulée, zéro sinon.

Remarques

La nouvelle fenêtre devient la fenêtre active sans avoir besoin d'utiliser SetActiveWindow() (sauf si elle a été créée en mode invisible).

Si le paramètre facultatif 'Options' n'est pas renseigné, #PB_Window_SystemMenu sera utilisé par défaut.

Tous les évènements possibles dans une fenêtre sont gérés par les commandes WindowEvent() et WaitWindowEvent(). Pour les situations spéciales les callbacks sont utilisées, voir la description de SetWindowCallback(). Sous Windows, la largeur et la hauteur d'une fenêtre avec une barre de titre ne peuvent pas être inférieur à environ 100 pixels. Pour ouvrir une fenêtre plus petite, utiliser l'option #PB_Window_BorderLess.

Note: Une fenêtre ne devrait pas être ouverte dans un thread, car il y a une limitation sur OS X et Linux. Une erreur du débogueur sera levée.

Exemple

  If OpenWindow(0, 0, 0, 220, 100, "Exemple...", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)

   ButtonGadget  (1, 10, 60, 200, 30, "Fermer")
   
   Repeat
     Event = WaitWindowEvent()
     
     Select Event
     
       Case #PB_Event_Gadget
         Select EventGadget()
           Case 1 
              CloseWindow(0)
              End  
         EndSelect
            
     EndSelect
   Until Event = #PB_Event_CloseWindow
 EndIf

Voir aussi

CloseWindow()

OS Supportés

Tous

<- IsWindow() - Window Index - PostEvent() ->